Några sidor - Inet (Microsoft Internet Transfer Control)

Det finns många sätt att hantera nätverk med hjälp av VB. Ett av de enklaste sätten är att använda sig av Inet kontrollen som kapslar HTTP och FTP protokollen.

Det kan kanske kännas onödigt att skriva egna program för hantering av dessa protokoll eftersom man oftast använder HTTP i en browser, och det dessutom finns färdiga FTP program att ladda ner från Internet. Det har dock visat sig att man kan behöva dessa.

För att använda Inet kontrollen måste man välja Projekt, Components menyn eller högerklicka på toolboxen (som oftast finns längst till vänster i VB:s miljö). I listan som kommer skall man välja ("kruxa för") Microsoft Internet Transfer Control X.0, där X är 5 för VB 5.0 och 6 för VB 6.0. I toolboxen kommer då en ny Inet komponent som ser ut som en liten jordglob med en dator framför sig. Om ni använder en miljö där inte kontroller kan användas direkt kan ni använda er av
Set objekt = CreateObject("InetCtls.Inet.1") för att få tillgång till Intekontrollens funktionalitet. I ASP används
Set objekt = Server.CreateObject("InetCtls.Inet.1")

I alla exempel antas att ni har en Inet kontroll placerad på formen och att den heter Inet1.

Inet kontrollens properties (jag tar bara upp de egenskaper som är unika för denna typ av kontroll, bland annat Name och Index som finns för de flesta kontrolltyper tas inte upp):

I praktiken HTTP

För att överföra data över Internet med hjälp av Inet kontrollen så används antingen OpenURL eller Execute. Den enklaste (men kanske inte alltid bästa) metoden är OpenURL som fungerar som följer:

Metod: OpenUrl
Syntax: returvariabel = Inet1.OpenUrl( url [,datatyp] )
och datatyp kan vara något av följande:
icString (0 - default): OpenURL returnerar en text. Tex. en html fil eller en textfil
icByteArray (1): OpenURL returnerar binär tdata, t.ex en exe, eller gif fil.

Om vi är säkra på att det är en textfil kan vi använda Inet kontrollen på följande sätt:

Private Sub Command1_Click()
      Dim Resultat As Variant
      Resultat = Inet1.OpenURL("http://www.site.com/fil.htm")
      ' och sen så gör vi någonting av innehållet i
      ' resultat variabeln
      ' för exemplets skull sparar jag i en fil
      Open "C:\Temp\test.txt" For Output As #1
      Print #1 , Resultat
      Close #1
End Sub

Och om vi är säkra på att datat är binärt (exe, zip jpeg eller liknande) kan vi även göra på detta sätt:

Private Sub Command1_Click()
      Dim resultat() As Byte ' observera att vi måste använda en array
      Resultat() = Inet1.OpenURL("http://www.site.com/test.zip", _
                  icByteArray)
      ' och sen så gör vi någonting av innehållet i
      ' resultat variabeln
      ' för exemplets skull sparar jag i en fil
      Open "C:\Temp\test.zip" For Binary Access Write As #1
      Put #1, , Resultat()
      Close #1
End Sub

Problemet med OpenURL är att vi bara sparkar igång en nedladdnin och har ingen koll på vad som sker. Vi har inte heller någon möjlighet att kontrollera typen av data i förväg. Vi har inte heller någon möjlighet att utföra någonting annat än en simpel "download"...

Private Sub Command1_Click()
      If Inet1.StillExecuting Then
            Inet1.Cancel
      End If
      Inet1.URL = Text1.Text
      Inet1.Execute Inet1.URL, "GET"
      Do While Inet1.StillExecuting
            DoEvents
      Loop
End Sub

Private Sub Inet1_StateChanged(ByVal State As Integer)
      Dim theResponseType As String
      Dim strData As String
      Dim vtData As Variant
      Dim vtDataTmp As Variant
      Dim byteData() As Byte
      Dim saveFile As String

      Select Case State
            ' allt data finns tillgängligt
            Case icResponseCompleted
                  ' vad har vi fått för typ av fil?
                   theResponseType = Inet1.GetHeader("Content-type")

                  ' kolla filnamnet
                  saveFile = ReverseSpanExcluding(Inet1.Document, "/")

                  ' om man inte anger filnamn utan para katalog får man en default fil
                  ' i så fall är inte Inet1.Document satt utan vi måste kolla
                  '                   If Len(saveFile) = 0 Then
                        saveFile = ReverseSpanExcluding( _
                                           Inet1.GetHeader("Content-location"), "/")
                  End If

                  Select Case theResponseType
                        '                          Case "text/plain", "text/html"
                              vtData = Inet1.GetChunk(1024, icString)
                              Do While LenB(vtData) > 0
                                    strData = strData & vtData
                                    vtData = Inet1.GetChunk(1024, icString)
                              Loop
                              ' gör något med datat. I detta fall en lagring
                              Open "C:\" & saveFile For Output As #1
                              Print #1, strData
                              Close #1
                        Case Else
                              ' binärt data ?
                              vtData = Inet1.GetChunk(1024, icByteArray)
                              Do While LenB(vtData) > 0
                                    vtDataTmp = vtDataTmp & vtData
                                    vtData = Inet1.GetChunk(1024, icByteArray)
                              Loop
                              byteData = vtDataTmp
                              Open "C:\" & saveFile For Binary Access Write As #1
                              Put #1, , byteData
                              Close #1
                   End Select
             Case Else
                        ' här borde väl minst icError (11) kollas
      End Select
End Sub

' några stödfunktioner...
Function ReverseSpanExcluding(S, sSök)
      S = Reverse(S)
      If Len(S) = 0 Then
            ReverseSpanExcluding = Empty
      Else
            ReverseSpanExcluding = Reverse(Left$(S, InStr(1, S, sSök) - 1))
      End If
End Function

Function Reverse(ByVal sSträng)
      Dim sRev As String
      Dim iVarv As Integer
      sRev = ""
      For iVarv = Len(sSträng) To 1 Step -1
            sRev = sRev + Mid(sSträng, iVarv, 1)
      Next iVarv
      Reverse = sRev
End Function

Vill ni veta mer kan ni till exempel söka fram artikel Q229666 i Microsofts Knowledge Base.